1.筆跡データの永久 SAS ファイル化

2. 筆跡データの重回帰分析及び因子間相関プログラム

3.筆跡データの分析結果とその見方

　この節には、つぎの２つの SAS プログラムのダウンロードコーナーを用意して あります：

1.永久 SAS ファイル用プログラムの例

2.重回帰分析用プログラムの例２

 11 2 5   11 9 81015          18191617171014 513 6 313                          
 12      4.3 3.0 4.8 3.5 4.3 4.8 5.7 4.3 2.7 5.5 5.5 3.5 6.0 5.2 2.8 4.2 3.2 4.5
 13      5.0 3.8 3.5 3.5 2.7 5.7 3.5 3.7 3.5 4.2 846                            
 1          0.27  1.49 -0.61 -1.48 -0.68            1.74 -0.37          0.89    
 21 5 5    711 6 812          11141615 7 8 7 7 3 4 6 9                          
 22      4.5 3.8 4.5 4.7 4.2 3.5 4.7 3.2 3.7 3.7 3.5 4.5 2.8 4.5 4.2 3.7 3.3 3.7
 23      4.3 4.3 4.7 4.0 4.8 4.8 4.3 3.8 4.2 5.7 530                            
 2         -0.03 -0.68  0.07  0.16  0.98            0.33  1.24          0.31   
               .................................................
               .................................................
               ................................................. 
501 1 6    7 2 2 2 3          1217 9 911 6 9 71712 610                          
502      4.7 4.3 4.3 1.8 1.8 4.7 2.8 4.0 3.7 4.8 4.5 2.5 4.5 2.8 2.2 3.2 3.5 3.0
503      2.2 2.0 4.0 3.0 3.5 3.7 2.7 1.8 4.0 4.8 786                            
50         -1.73  1.32  1.15 -0.50  0.60            0.23 -0.42         -1.69    

　 このような結果を手にした時、性格の筆跡に及ぼす影響を検討する１つの方法は、 まず筆跡のデータを分析し、その基本的次元（因子）を明らかにし、得られた筆跡 （の各次元上での各被験者の値）を基準変数とし、性格検査を構成する複数の下位 尺度得点を説明ないし予測変数とする重回帰分析を行うことである。

　 このようなデータの場合、筆跡の基本的次元（因子）は陽に与えられたもので はなく、つぎの章で説明する因子分析という方法を経由して間接的にしか与えら れない尺度であることに注意したい。

　 いずれにせよ、SAS による分析に先立ち、まず Table 2.3 のデータを永久 SAS ファイルに登録することにしよう。Table 2.3 から明らかなように、このデータは １人分が４行で合計 200行（50 名分）から成るので、Table 2.2 の場合のようにプロ グラムの中にデータを入れるのではなく、データはあらかじめ適当なファイルに 入力しておき、プログラムの中では単にそれを呼び出すだけで済ませることにする。

*---------------------------------------------------------------------*
|                                                   September 2, 2018 |
|  sas program--perm_Fuj.sas--                                        |
|       a sas program for making a second sas permanent file of Fujii |
|  data.  This data is a part of the Fujii (79p103, Utsumi Fujii).    |
|                                                                     |
|  file name: c:\sasprog\perm_Fuj.sas                                 |
|                                                                     |
*---------------------------------------------------------------------*;
filename data "/folders/myfolders/data/p79103uf.txt";
libname sasfile "/folders/myfolders/permfile";
data sasfile.Fujiiraw;
  infile data;
  input ssno 2. +8 (inv1-inv5) (2.) +10 (yg1-yg12) (2.)
        / +8 (img1-img18) (+1 3.1) / +8 (img19-img28) (+1 3.1)
          +1 img29 3. / ;
  label ssno='sample no'
        yg1='depression'
        yg2='cyclic tendency'
        yg3='infereiority complex'
        yg4='neurosis'
        yg5='objectivity'
        yg6='cooperativeness'
        yg7='aggressiveness'
        yg8='general activity'
        yg9='rhathymia'
        yg10='thinking extroversion'
        yg11='ascendance'
        yg12='social extroversion'
        img1-img29='sd-scale for the image of holographs';
run;
options pagesize=66;
proc print data=sasfile.Fujiiraw n;
 title 'proc print out for the sas Fujii raw data';
run;
  

　 第１行の filename 文は、Table 2.3 のデータが、ユーザのホームディレクトリの 下の p79103uf.txt なる名前をつけたファイルに保存されており、それをファイル参照名 data で略すことを宣言している。

　 第２行の libname 文は、省略する。

　 第４行の infile 文は、参照名 data なるファイル、すなわち第１行で指定した ファイルを読みだすことを指示している。

　 第５行の input 文は、Table 2.3 のデータのうち、当面の解析に必要なもの だけの変数名とそれらの書式を指定したものである。文中の「/」は、行換えを 指示している。一人文のデータは、多くの場合このように複数行から成るので、 この記号が必要となることが多いであろう。

　 つぎの label 文であるが、その中の最後の定義はたくさんの変数に単一の ラベルをつけて省略するやり方である。ただし、このように省略すると、最後の 変数（この場合、img29）のみに変数ラベルがつけられ、残りの変数にはラベルが つかないので注意されたい。また、inv1 から inv5 については、ラベル を定義していないことに注意したい。このように、定義を省略することもできる。

　 最後の３行の print 文については、既に説明したので省略する。

　 つぎのプログラムは、Table 2.3 の筆跡データの重回帰分析及び筆跡の因子と YG 性格の因子間の相関係数を計算し検定するためのものである。

*---------------------------------------------------------------------*
|                                                       April 6, 2005 |
|  sas program--mreg_ex2.sas--                                        |
|       example 2 of sas programs for multiple regression.            |
|                                                                     |
|  file name: c:\sasprog\mreg_ex2.sas                                 |
|                                                                     |
*---------------------------------------------------------------------*;
libname sasfile 'c:\permfile';
options pagesize=60;
  title 'principal FA for the holograph data';
proc factor data=sasfile.Fujiiraw
  /* method options */ method=p priors=max n=5 rotate=v
  /* output options */ score outstat=factout;
  var img1-img29;
run;
proc score data=sasfile.Fujiiraw score=factout out=scores;
run;
  title 'multiple regressions for the Fujii data';
proc reg data=scores simple corr;
  model factor1-factor5=inv1-inv5 yg1-yg12;
run;
data factran1;
  set scores;
  array imgf{5};
  array imgfact{5} factor1-factor5;
    do j=1 to 5;
      imgf{j}=imgfact{j};
    end;
  drop yg1-yg12 img1-img29;
  output;
run;
  title 'principal FA for the YG data';
proc factor data=sasfile.Fujiiraw
   method=p priors=max n=2 rotate=v
   score outstat=factout;
  var yg1-yg12;
run;
proc score data=sasfile.Fujiiraw score=factout out=scores;
run;
data factran2;
  set scores;
  rename factor1=ygf1 factor2=ygf2;
  drop yg1-yg12 img1-img29;
  output;
run;
data allfact;
  merge factran1 factran2;
run;
proc corr data=allfact;
  var imgf1-imgf5 ygf1-ygf2;
run;
quit;

　 上のプログラムでは、筆跡や YG 性格検査の因子の数は、あらかじめ行った 因子分析により、それぞれ 5、2 と確定していることを仮定している。因子分析 の詳細については、第３章を参照のこと。

　 また、このプログラムでは、筆跡の各因子の因子得点（個人差得点）を基準 変数とし２種類の性格検査の得点を説明ないし予測変数とする重回帰分析だけで はなく、筆跡の因子と YG 性格検査の因子との間の（単）相関係数とその検定結果 もみれるようにしてある。

　 一方、Table 2.2 の卒論データの場合のような、多変量解析に先立つ基礎集計 は、出力しない。これについては、必要に応じてユーザが加えるとよい。

　 第４行からの factor プロシジャは、筆跡の２９項目への５名の評定者の評定 の平均値を各被験者の筆跡得点としたものに対して、５因子解を指定したもので ある。プロシジャ中、方法のオプションで主因子解 (method=p)、共通性の初期値 として相関行列の各行または列の要素の絶対値最大なもの（の絶対 値）(priors=max)、因子数は５ (n=5)、及び因子軸の回転方法としてバリマックス 回転 (rotate=v) を指定した。このプロシジャではさらに score オプションで、 各被験者の因子得点計算のための情報を factout なる一時ファイルに出力させ ている。

　 つぎの score プロシジャは、factor プロシジャの score オプションで出力 されたファイル及びもとのデータ（永久 SAS ファイル, sasfile.Fujiiraw）を 呼び出して、各被験者の因子得点を計算し、一時ファイル scores に出力させる ためのものである。この時、一時ファイル scores には、各被験者の因子得点 だけでなく、もとのデータも保存される。

　 このようにして一旦保存した因子得点と、もとの変数の値を使い、筆跡の各因子 を基準変数とし、２種類の性格検査の得点を説明ないし予測変数とする重回帰分析 を実行させるためのプログラムが、つぎの reg プロシジャである。変数数が多い ので、corr オプションは削った方が出力が少なくて済む。

　 つぎの data 文では、一時ファイル scores に保存されている筆跡の因子得点 を呼び出し、factor1 から factor5 までの因子得点を新たな imgfact1 から imgfact5 なる変数に名前の変更を行う。この SAS プログラムが面倒なユーザは、 これを

  data factran1;
    set scores;
    rename factor1=imgf1 factor2=imgf2 factor3=imgf3
           factor4=imgf4 factor5=imgf5;
    drop yg1-yp12 img1-img29;
    output;
  run;
  

と書いてもよい。なぜ、このようなことを行うかというと、SAS の因子分析プロ グラムでは、因子名はこちらがあらかじめ指定することができず、今回のように ２種類の因子分析を行い因子間の相関を見たいような場合には、因子名の重複を 避けるために、それぞれの因子分析により SAS により自動的に命名される factor1、 factor2、などを両者で区別する必要があるからである。また、このように改名 された５因子の因子得点を、data 文のすぐ右のファイル名 factran1 と指定する ことにより、そこに一時的に保存させることができる。

　 つぎの factor プロシジャは、YG 性格検査の得点の因子分析を指示するもので ある。その後の score プロシジャは、先ほどと同様、直前の因子分析結果から因子 得点計算のための情報を factout なる一時ファイルから受け取り、因子得点を 計算し、やはり一時ファイル scores に保存するためのものである。

　 つぎの data 文は、直前の一時ファイル scores を set 文で受け取 り、rename 文で性格検査の２因子の名前を、 factor1、factor2 から ygf1、及 び ygf2 へと変更するためのものである。この変更結果は、一時ファイ ル factran2 に保存される。

　 つぎの date 文では、２つの一時ファイル factran1 と factran2 を変数方向 に結合させるためのもので、merge 文を用いている。また、結合した結果をフィアル allfact なる一時ファイルに保存することをも指示している。

　 最後の corr プロシジャは、因子得点間の相関係数とその検定を行うためのも のである。

　 上述の一連のプログラムを実行させると、つぎのような結果が得られる。因子 分析の結果の説明の詳細は、ここでの主目的ではないので、因子の解釈に必要な 因子パターン（因子負荷行列）のみ示すことにする。詳細は、第３章を参照のこと：

1. 筆跡データの因子分析結果
   1. 共通性の事前初期推定値 (Prior Communality Estimates)
   2. 縮退相関行列の固有値とその％ (Eigenvalues of the Reduced correlation matrix)
   3. 初期因子法：主因子 (Initial Factor Method: Principal Factors)
   4. 回転法：バリマックス (Rotation Method: Varimax)

      　 ここでは、前項で出力される回転前の因子パターンに対する直交回転行列 の出力に続いて、バリマックス回転後の因子パターンがつぎのように出力され る。ここで、右側の各項目のラベルは、プログラムで省略しており、本来 ならば出力されないものを、後で編集の際に加えたものである。上述の SAS の label 文の引用符の中に日本語で指定すれば、出力結果にも自動的にプリント される：

      Rotated Factor Pattern FACTOR1 FACTOR2 IMG1 0.07387 0.03172 右上がりー右下がり IMG2 0.66091 0.15353 間隔が広いー間隔が狭い IMG3 -0.02623 -0.01931 縦長ー横長 IMG4 0.87447 -0.21176 きれいなーきたない IMG5 0.92396 -0.16159 ていねいなー雑な IMG6 0.24834 0.80103 大きいー小さい IMG7 0.63210 0.18383 行がまっすぐー行が曲がっている IMG8 -0.26440 0.32200 硬いーやわらかい IMG9 0.41911 0.07685 鋭いー鈍い IMG10 -0.05924 0.86257 線が太いー線が細かい IMG11 0.07326 0.90470 強いー弱い IMG12 0.77457 0.05727 しまりがあるーしまりがない IMG13 -0.00533 0.88305 重いー軽い IMG14 0.82011 0.28923 くっきりしたーあいまいな IMG15 0.90234 -0.04711 字形が整っているー字形が整っていない IMG16 0.61529 0.59588 豊かなー貧弱な IMG17 0.12159 0.40607 抑揚があるー抑揚がない IMG18 0.68213 0.10128 行間隔が均一ー行間隔が均一でない IMG19 0.81767 0.06467 留め払いがきちんとしているーしていない IMG20 0.92424 0.06793 よいー悪い IMG21 0.40339 -0.07762 なめらかなーこつこつした IMG22 -0.04470 0.09581 角ばったー丸っこい IMG23 -0.62168 -0.12372 文の始めと終わりで字が変るー変らない IMG24 0.77130 -0.03025 筆圧が一定ー筆圧が一定でない IMG25 0.80739 -0.31462 かわいいーにくらしい IMG26 0.92254 0.05104 読みやすいー読みにくい IMG27 -0.76764 -0.25338 まっすぐなーのびのびとした IMG28 -0.11781 0.44347 漢字が大きいー漢字が小さい IMG29 0.19794 0.25147 （転記時間が）速いー遅い

      --- 筆跡２９項目のバリマックス回転後の因子パターンの一部 （１）---

      　 上の結果から、各因子に負荷の高い（因子負荷量の絶対値が相対的に大きい） 項目を因子ごとに見てみると、第１因子は、項目２０、５、２６、１５などに 高い負荷を示しており、筆跡の評価因子と命名できよう。また、第２因子は、 項目１１、１３、１０、６などに高い負荷をしており、筆跡の力強さの因子 と命名する。

      Rotated Factor Pattern FACTOR3 FACTOR4 IMG1 0.11736 0.60055 IMG2 -0.24802 -0.15355 IMG3 0.09158 0.19064 IMG4 -0.25093 0.13866 IMG5 0.09301 -0.02197 IMG6 -0.12458 -0.10913 IMG7 0.02060 0.09965 IMG8 0.80872 -0.02304 IMG9 -0.06588 0.76572 IMG10 0.22004 -0.06334 IMG11 0.17117 0.24962 IMG12 0.06359 0.52943 IMG13 0.26022 0.14991 IMG14 0.21018 0.16121 IMG15 -0.15187 0.27829 IMG16 -0.11786 0.32776 IMG17 -0.19275 0.68009 IMG18 -0.13925 0.07151 IMG19 0.26519 0.03561 IMG20 -0.16874 0.19452 IMG21 -0.73312 0.23508 IMG22 0.86055 0.03899 IMG23 0.22946 -0.28392 IMG24 -0.23189 -0.08006 IMG25 -0.29447 0.04178 IMG26 -0.22732 0.01924 IMG27 0.33251 0.10116 IMG28 -0.02826 0.13350 IMG29 0.16529 -0.19222 sd-scale for the image of holographs

      --- 筆跡２９項目のバリマックス回転後の因子パターンの一部 （２）---

      　 上の結果から、第３因子は項目２２、８、２１などに高い負荷を示しており、 筆跡の滑らかさの因子と命名する。同様に、第４因子は項目９、１７、１などに 高い負荷をしており、筆跡のアクセント因子と命名する。
      

      　 第５因子については、負荷の高い項目が１つしかないので、因子の命名を 行わないことにする。

      Variance explained by each factor FACTOR1 FACTOR2 FACTOR3 FACTOR4 FACTOR5 10.536688 4.308508 2.877067 2.346604 1.189428

      つぎに、うえのような因子寄与が出力される。この値は、回転後の各因子の 因子負荷量の二乗和であり、共通因子空間での因子の寄与の大きさを表す。

      Final Communality Estimates: Total = 21.258295 IMG1 IMG2 IMG3 IMG4 IMG5 IMG6 0.546177 0.787869 0.430230 0.894857 0.889444 0.807736 IMG7 IMG8 IMG9 IMG10 IMG11 IMG12 0.445411 0.829750 0.789346 0.819362 0.922404 0.887969 IMG13 IMG14 IMG15 IMG16 IMG17 IMG18 0.889888 0.828789 0.918472 0.862523 0.679742 0.500188 IMG19 IMG20 IMG21 IMG22 IMG23 IMG24 0.777671 0.925563 0.801782 0.786993 0.540496 0.656004 IMG25 IMG26 IMG27 IMG28 IMG29 0.858305 0.905765 0.839860 0.268353 0.167344

      --- 筆跡２９項目の最終的な共通性の推定値 ---

      　 つぎに、各項目の最終的な共通性の推定値がうえのような形で出力される。 共通性は、各項目の共通因子空間内での寄与の大きさを表す。

   5. 回帰推定法によるスコア係数 (Scoring Coefficients Estimated by Regression)
2. 重回帰分析結果
   1. 記述統計結果 (Descriptive Statistics)
   2. 変数相互の相関 (Correlation)
   3. 重相関係数の統計的有意性の分散分析結果

      　 つぎに、筆跡の各因子を基準変数とし、２種類の性格検査の下位尺度を説明 変数とする重回帰分析における重相関係数の統計的有意性の検定結果が分散 分析の形で出力される。既述のプログラムでは、基準変数を同時に複数個指定 しているので、SAS は、それらの１つ１つについて重回帰分析を行い、順に 結果を出力する。
      

      　 したがって、つぎに出力されている最初の重回帰分析結果は、基準変数を 筆跡の第１因子とし、説明ないし予測変数を２種類の性格検査の下位尺度と した場合のものである。

      Model: MODEL1 Dependent Variable: FACTOR1 Analysis of Variance Sum of Mean Source DF Squares Square F Value Prob>F Model 17 17.07518 1.00442 1.035 0.4509 Error 32 31.06055 0.97064 C Total 49 48.13573 Root MSE 0.98521 R-square 0.3547 Dep Mean 0.00000 Adj R-sq 0.0119 C.V. 4.4369992E18

      --- 筆跡の第１因子についての重回帰分析における重相関係数の検定結果 ---

      　上の結果の見方については、既にTable2.2の卒論データのところで説明して あるのでここでは省略し、結果についてのみ述べる。上の結果から、Prob $>$ F の 値が 0.4509 と大きい（５％水準、すなわち統計的に有意という時の通常の限界 値 0.05 より大きな値）ので、筆跡の第１因子 (FACTOR1) すなわち、筆跡の評価 因子（筆跡のよしあしのレベル）は、INV や YG 性格検査によっては説明ないし 予測できないという結論に達する。
      

      　 この例のように、重相関係数が有意でないときは、どの説明変数が基準変数に 効いているかという議論は意味を成さないので、つぎに出力される偏回帰係数の 検定結果は無視する必要がある。したがってここでは、この結果は省略する。
      

      　 基準変数が第２因子の場合も上と同様に見てみると、第１因子と同様、重相関係 数は統計的に有意でなかった（F(17, 32)=0.734)。そこで、これについての結果も ここでは省略する。
      

      　 つぎの結果は、筆跡の第３因子を基準変数とした場合の重相関係数の検定結果 である。

      Dependent Variable: FACTOR3 Analysis of Variance Sum of Mean Source DF Squares Square F Value Prob>F Model 17 22.05124 1.29713 1.800 0.0740 Error 32 23.05723 0.72054 C Total 49 45.10846 Root MSE 0.84885 R-square 0.4888 Dep Mean 0.00000 Adj R-sq 0.2173 C.V. 2.9866088E17

      --- 筆跡の第３因子についての重回帰分析における重相関係数の検定結果 ---

      　 上の結果からは、Prob $>$ F=0.0740 と、５％水準には満たないが、基準変数と 説明ないし予測変数の間には傾向程度の関係があるといえる。そこで、つぎに出力 される偏回帰係数の検定結果を見て、どの変数が基準変数である筆跡の滑らかさ の因子（筆跡の滑らかさのレベル）に効いているのかを検討することにする。

      Parameter Estimates Parameter Standard T for H0: Variable DF Estimate Error Parameter=0 Prob > |T| INTERCEP 1 1.480802 1.23177847 1.202 0.2381 INV1 1 0.050274 0.05892222 0.853 0.3999 INV2 1 -0.123026 0.04818925 -2.553 0.0157 INV3 1 -0.094140 0.06554161 -1.436 0.1606 INV4 1 0.024011 0.06054456 0.397 0.6943 INV5 1 0.093944 0.05422526 1.732 0.0928 YG1 1 0.000485 0.04094124 0.012 0.9906 YG2 1 -0.098231 0.05144064 -1.910 0.0652 YG3 1 0.004801 0.04111924 0.117 0.9078 YG4 1 0.041149 0.05834989 0.705 0.4858 YG5 1 0.028614 0.04803101 0.596 0.5555 YG6 1 0.024462 0.05260075 0.465 0.6450 YG7 1 -0.000367 0.03940389 -0.009 0.9926 YG8 1 0.073315 0.04308059 1.702 0.0985 YG9 1 -0.022794 0.04349857 -0.524 0.6039 YG10 1 -0.041593 0.04472168 -0.930 0.3593 YG11 1 0.011826 0.05054101 0.234 0.8165 YG12 1 -0.107863 0.05273356 -2.045 0.0491 Variable Variable DF Label INTERCEP 1 Intercept INV1 1 循環性 INV2 1 粘着性 INV3 1 分裂性 INV4 1 ヒステリー INV5 1 神経質 YG1 1 depression YG2 1 cyclic tendency YG3 1 infereiority complex YG4 1 nervousness YG5 1 objectivity YG6 1 cooperativeness YG7 1 aggressiveness YG8 1 general activity YG9 1 rhathymia YG10 1 thinking extroversion YG11 1 ascendance YG12 1 social extroversion

      --- 筆跡の第３因子についての重回帰分析における偏回帰係数の検定結果 ---

      　 上の結果の Prob $> \mid T \mid$ の値の小さいもの（できれば 0.05 以下のもの） を探すと、INV2 のそれが 0.0157、YG12 のそれが 0.0491、YG2 のそれが 0.0652、 INV5 のそれが 0.0928 となっている。したがって、偏回帰係数は、INV2 及び YG12 が５％水準で統計的に有意、また YG2 及び INV5 が傾向程度で（基準変数と）関連 がある、といえる。
      

      　 それでは、筆跡の第３因子である筆跡の滑らかさのレベルとこれらの性格の間には 具体的にどのような関係があるといえるのであろうか。このことを明らかにするため には、あらかじめ、以下のような幾つかの点に注意する必要がある。
      

      　 まず第一に、因子得点（因子上のいわば個人差得点）の正負の方向性を明らかに しておく必要がある。そのためには、上述の因子分析により得られた因子パターン を各因子ごとに見て行き、当該因子との因子負荷量の値の絶対値が最大のものに対応 する変数をみつけるとよい。第３因子の場合、それは IMG22 すなわち SD 尺度「角 ばったー丸っこい」であり、因子負荷量は 0.86055 である。上述のような直交因子 の場合、因子負荷量は因子と各変数の間の相関係数に等しいので、この符号ともと の変数の得点との関係から、因子（得点）の正負を調べることができるのである。
      

      　 ところで、この調査での SD 尺度は７段階評定尺度で、各両極性尺度とも尺度の 左側の評定尺度カテゴリー（非常に）から順に右方向に７点、６点、$\cdots$ 、１ 点と得点化した。したがって、第３因子と相関の最も高い変数「角ばったー丸っこ い」との相関係数 0.86055 は、第３因子の正方向が（筆跡が）「滑らかでない」こ とを、逆に第３因子の負の方向が「滑らかである」ことを意味する。
      

      　 第二に、第３因子に効いている変数の得点の高低のもつ意味を明らかにしておく 必要がある。まず、INV の下位尺度については、すべて得点が高い程当該特性を 被験者は多く持っていることを意味する。つぎに、YG の下位尺度については、筆跡 の第３因子に効いているとみなされた YG2 と YG12 についてのみ見てみると、YG2 は、「気分の変化」(cyclic tendency) を測る尺度であり、得点が高い程被験者は 気分の変化が大きいことを意味する。また、YG12 は、「社会的外向性」(social extroversion) の尺度であり、得点が高い程被験者は社会的に外向的であることを 意味する。
      

      　 第三に、うえの出力結果に Parameter Estimate として印刷されている偏回帰 係数の符号は、偏相関係数のそれと同一であるということである。
      

      　 これら３点を踏まえると、偏回帰係数が統計的に有意な２尺度、INV2 と YG12、 及び傾向程度の関連のある２尺度 YG2 と INV5 のそれぞれと筆跡の第３因子との 関係は、つぎのようであるといえる。
      

      　 まず、INV2 と筆跡の第３因子、すなわち筆跡の滑らかさのレベルとの関係は、 上の表における偏回帰係数が -0.123026 となっておりその符号が負、すなわち偏 相関係数が負であるので、粘着性格の被験者すなわち物事に執着したり、根気強く、 融通が効かないタイプの者は、そうでない者に比べてより滑らかな筆跡を示すと いえる。また、YG12 については偏回帰係数が -0.107863 とやはり負になっており、 社会的に外向的な者のほうが、そうでないものに比べてより滑らかな筆跡を示す、 といえる。
      

      　 一方、YG2 の偏回帰係数が -0.098231 とやはり負なので、気分の変化が大きい 者程、そうでない者に比べて、より滑らかな字を書く傾向がある、といえる。また、 INV5 の偏回帰係数は 0.093944 と正なので、神経質な性格の者程、そうでない者 に比べて滑らかでない字を書く傾向があるといえる。
      

      　 第４因子を基準変数にした場合の重相関係数も、検定結果を見ると統計的に 有意ではなかったので、ここでは省略する。第５因子の場合は、重相関係数は 傾向程度の関連性を示したが、基準変数としてのこの因子の解釈がむずかしかった ので、考察の対象から外すことにする。

3. YG 性格検査の因子分析結果

   　 つぎの出力結果は、YG 性格検査の因子分析結果を示す。ここでも、出力のうち、 最初の２項目、すなわち共通性の初期推定値、縮退相関行列の固有値やそのパ ーセント、回転前の因子パターン、最終的な共通性の推定値、直交回転行列につい ては省略し、回転後の因子パターンをつぎに示す。

   Rotated Factor Pattern FACTOR1 FACTOR2 YG1 0.75952 -0.22096 depression YG2 0.77913 -0.07544 cyclic tendency YG3 0.59895 -0.53962 infereiority complex YG4 0.78659 -0.37213 neurosis YG5 0.75912 -0.14434 objectivity YG6 0.62930 0.07055 cooperativeness YG7 0.34680 0.36703 aggressiveness YG8 -0.28473 0.67426 general activity YG9 0.07831 0.47869 rhathymia YG10 -0.57557 0.15191 thinking extroversion YG11 -0.31029 0.79626 ascendance YG12 -0.25876 0.77030 social extroversion

   --- YG 性格検査の主因子解、バリマックス回転後の因子パターン ---

   　 つぎに、２因子の因子寄与と最終的な各変数の共通性の推定値が出力される：

   Variance explained by each factor FACTOR1 FACTOR2 3.835637 2.578949 Final Communality Estimates: Total = 6.414586 YG1 YG2 YG3 YG4 YG5 YG6 0.625692 0.612730 0.649924 0.757202 0.597094 0.401001 YG7 YG8 YG9 YG10 YG11 YG12 0.254985 0.535702 0.235279 0.354353 0.730312 0.660312

   --- YG 性格検査の２因子の因子寄与 ---

   　 最後の、因子得点計算のための係数は省略する。

4. 筆跡の５因子と YG 性格検査の２因子との相関関係

   　 最後に、筆跡の５因子と YG 性格検査の２因子との相関関係が corr プロシジャ により出力される。これら７変数の相関行列とその検定結果が表示される前に、 各変数の平均や標準偏差の情報がつぎのように出力される。これらの変数は、 すべて因子得点であるので、平均はゼロ、標準偏差はほぼ１になっていること に注意せよ。

   Correlation Analysis 7 'VAR' Variables: IMGF1 IMGF2 IMGF3 IMGF4 IMGF5 YGF1 YGF2 Simple Statistics Variable N Mean Std Dev Sum Minimum Maximum IMGF1 50 0 0.9911 0 -1.9284 1.8115 IMGF2 50 0 0.9893 0 -2.2734 1.6645 IMGF3 50 0 0.9595 0 -2.1204 1.6482 IMGF4 50 0 0.9491 0 -2.2200 2.0895 IMGF5 50 0 0.9166 0 -1.9547 1.7855 YGF1 50 0 0.9430 0 -2.1298 1.7961 YGF2 50 0 0.9237 0 -1.4853 2.0039

   --- 筆跡の５因子と YG 性格検査の ２因子の各々の平均と標準偏差等 ---

   　 最後に、つぎのような７変数（７因子）間の相関行列とその検定結果が出力 される：

   Pearson Correlation Coefficients / Prob > |R| under Ho: Rho=0 / N = 50 IMGF1 IMGF2 IMGF3 IMGF4 IMGF5 YGF1 YGF2 IMGF1 1.00000 0.00557 -0.01677 0.01952 0.00699 -0.01233 0.06680 0.0 0.9694 0.9080 0.8930 0.9616 0.9323 0.6448 IMGF2 0.00557 1.00000 0.01404 0.01047 -0.00149 -0.10228 0.03671 0.9694 0.0 0.9229 0.9425 0.9918 0.4797 0.8002 IMGF3 -0.01677 0.01404 1.00000 0.00693 -0.00152 -0.03065 -0.31657 0.9080 0.9229 0.0 0.9619 0.9916 0.8327 0.0251 IMGF4 0.01952 0.01047 0.00693 1.00000 -0.00624 -0.04897 0.22682 0.8930 0.9425 0.9619 0.0 0.9657 0.7356 0.1132 IMGF5 0.00699 -0.00149 -0.00152 -0.00624 1.00000 -0.24223 -0.20638 0.9616 0.9918 0.9916 0.9657 0.0 0.0901 0.1504 YGF1 -0.01233 -0.10228 -0.03065 -0.04897 -0.24223 1.00000 -0.07075 0.9323 0.4797 0.8327 0.7356 0.0901 0.0 0.6254 YGF2 0.06680 0.03671 -0.31657 0.22682 -0.20638 -0.07075 1.00000 0.6448 0.8002 0.0251 0.1132 0.1504 0.6254 0.0

   --- 筆跡の５因子と YG 性格検査の ２因子相互の相関行列と相関係数の検定 結果 ---

   　 この表のうち、筆跡の因子間、及び YG 性格検査の因子間の相関係数はすべて ほぼゼロで、統計的にも有意でないことは明らかである。この結果は、この場合 直交因子を仮定しているので、このようになって当り前である。問題は、２種類の 因子間の相関関係である。これらについて見てみると、YGF2 すなわち YG の第２ 因子と IMGF3 すなわち 筆跡の第３因子との間のみが、統計的に５％水準で有意 となっている。
   

   　 YG の第２因子は、活動性の高さを表し得点が高い程、被験者の活動性が高いこと を意味する。また、筆跡の第３因子は筆跡の滑らかさのレベルを表し、得点が高い ほど被験者は滑らかでない字を書く。その結果、両者の間の有意な負の相関から、 活動性の高い者程、そうでない者に比べて滑らかな字を書くことがわかる。