5.2.3.2 節　RAM モデル文

　この節には、つぎの SAS プログラムのダウンロードコーナーを用意してあります：

LINEQS モデル文では、SEM の共分散構造を、内生変数に関する方程式と STD 文及び COV 文による外生誤差変数の分散及び共分散指定を用いて指示したが、 RAM モデル文では、RAM 構造の全てのパラメータは、必要なパラメータ行列の要素のみを指定すればよく、たいへんわかりやすい。RAM 構造の全てのパラメータは、 5.2.1 節の RAM 構造の最後で述べたように、２つの行列 K _R と Σ_exg により指定できることを思い出そう。また、前者は (5.20) 式、後者は (5.7) 式で与えられることも思い出そう。より具体的には、Wheaton et al. (1977) のデータの場合、両者はつぎのように書けることに注意しよう：

(5.33)

および、

(5.34)

ここで、後者の Σ _exg は、対称行列なので、下側３角行列のみ値を示した。

SAS の RAM モデル文では、つぎに示すようにこれら２つの行列の行番号を１、２とし、各行列のゼロでない要素の行番号、列番号、対応する要素の値（もし、対応する要素が自由母数または制約母数であれば、その初期値及びその母数の SAS 名も）を順に指定すればよい。

SAS の RAM モデル文の一般形はつぎの通り：

   RAM 
   　行列番号 行番号　列番号　<値>　<パラメータ名>,
   　行列番号 行番号　列番号　<値>　<パラメータ名>,
	    ..............................
   　行列番号 行番号　列番号　<値>　<パラメータ名>;

ここで、"値" には固定母数の場合その値を、自由母数の場合その初期値を充てる。また "パラメータ名" には、自由母数や制約母数の場合のみ、その SAS 名を記述する。

Wheaton et al. (1977) の例では、RAM モデル文を含めた CALIS のプログラム全体はつぎのようになる。このプログラムは、SAS/STAT Software (1997, p.23) の一部をこのテキスト用に修正し、さらに既に示した lineqs のプログラムの前半を加えたものである：

*-------------------------------------------------------------------------
*
*  A sas program for executing a CALIS procedure using RAM statements
*  for the Wheaton et al. (1977) data.
*
*-------------------------------------------------------------------------;
data Wheaton(type=cov);
  title "Stability of Alienation";
  title2 "data matrix of Wheaton, Muthen, Alwin & Summers (1977)";
  _type_ ='cov';
  input _name_ $ anoms powls anomo powlo yschl seind;
  label anoms='Anomia (1967)'
        powls='Powerlessness (1967)'
        anomo='Anomia (1971)'
        powlo='Powerlessness (1971)'
        yschl='Education'
        seind='Occupational Status Index';
  cards;
anoms  11.834    .       .       .       .       .
powls   6.947   9.364    .       .       .       .
anomo   6.819   5.091  12.532    .       .       .
powlo   4.783   5.028   7.495   9.986    .       .
yschl  -3.839  -3.889  -3.841  -3.625   9.610    .
seind -21.899 -18.831 -21.748 -18.775  35.522 450.288
;
proc calis data=Wheaton cov tech=nr edf=931 pall;
  ram
   1 1 7 1.         ,
   1 2 7  .833      ,
   1 3 8 1.         ,
   1 4 8  .833      ,
   1 5 9 1.         ,
   1 6 9  .5    lamb,
   1 7 9 -0.5   gam1,
   1 8 7   .5   beta,
   1 8 9 -0.5   gam2,
   2 1 1  3.    the1,
   2 2 2  3.    the2,
   2 3 3  3.    the1,
   2 4 4  3.    the2,
   2 5 5  3.    the3,
   2 6 6  3.    the4,
   2 3 1   .2   the5,
   2 4 2   .2   the5,
   2 7 7   4.   psi1,
   2 8 8   4.   psi2,
   2 9 9   6.   phi;
run;

プログラムのダウンロード・コーナー

sem-Wheaton-ram.sas

5.2.3.2 節 RAM モデル文

5.2.3.2 節　RAM モデル文